Qt QML Type

The application object provides access to global application state properties shared by many QML components.

Its properties are:

The object also has one signal, aboutToQuit(), which is the same as QCoreApplication::aboutToQuit().

The following example uses the application object to indicate whether the application is currently active:

 import QtQuick 2.0

 Rectangle {
     width: 300; height: 55
     color: Qt.application.active ? "white" : "lightgray"
     Text {
         text: "Application " + (Qt.application.active ? "active" : "inactive")
         opacity: Qt.application.active ? 1.0 : 0.5
         anchors.centerIn: parent
     }
 }

Note that when using QML without a QGuiApplication, the following properties will be undefined:

• application.active
• application.state
• application.layoutDirection
• application.font

This property was introduced in Qt 5.1.

See also Screen, Window, and Window.screen.

The inputMethod object allows access to application's QInputMethod object and all its properties and slots. See the QInputMethod documentation for further details.

This property was introduced in Qt 5.0.

The platform object provides info about the underlying platform.

Its properties are:

This property was introduced in Qt 5.1.

The styleHints object provides platform-specific style hints and settings. See the QStyleHints documentation for further details.

Note: The styleHints object is only available when using the Qt Quick module.

The following example uses the styleHints object to determine whether an item should gain focus on mouse press or touch release:

 import QtQuick 2.4

 MouseArea {
     id: button

     onPressed: {
         if (!Qt.styleHints.setFocusOnTouchRelease)
             button.forceActiveFocus()
     }
     onReleased: {
         if (Qt.styleHints.setFocusOnTouchRelease)
             button.forceActiveFocus()
     }
 }

This property was introduced in Qt 5.5.

The uiLanguage holds the name of the language to be used for user interface string translations. It is exposed in C++ as QQmlEngine::uiLanguage property.

You can set the value freely and use it in bindings. It is recommended to set it after installing translators in your application. By convention, an empty string means no translation from the language used in the source code is intended to occur.

If you're using QQmlApplicationEngine and the value changes, QQmlEngine::retranslate() will be called.

This property was introduced in Qt 5.15.

Use this function to eliminate redundant calls to a function or signal.

The function passed as the first argument to Qt.callLater() will be called later, once the QML engine returns to the event loop.

When this function is called multiple times in quick succession with the same function as its first argument, that function will be called only once.

For example:

 import QtQuick 2.0

 Rectangle {
     width: 480
     height: 320

     property int callsToUpdateMinimumWidth: 0
     property bool optimize: true

     property int currentTextModel: 0
     property var columnTexts: [
         ["Click on either", "rectangle above", "and note how the counter", "below updates", "significantly faster using the", "regular (non-optimized)", "implementation"],
         ["The width", "of this column", "is", "no wider than the", "widest item"],
         ["Note how using Qt.callLater()", "the minimum width is", "calculated a bare-minimum", "number", "of times"]
     ]

     Text {
         x: 20; y: 280
         text: "Times minimum width has been calculated: " + callsToUpdateMinimumWidth
     }

     Row {
         y: 25; spacing: 30; anchors.horizontalCenter: parent.horizontalCenter
         Rectangle {
             width: 200; height:  50; color: "lightgreen"
             Text { text: "Optimized behavior\nusing Qt.callLater()"; anchors.centerIn: parent }
             MouseArea { anchors.fill: parent; onClicked: { optimize = true; currentTextModel++ } }
         }
         Rectangle {
             width: 200; height:  50; color: "lightblue"
             Text { text: "Regular behavior"; anchors.centerIn: parent}
             MouseArea { anchors.fill: parent; onClicked: { optimize = false; currentTextModel++ } }
         }
     }

     Column {
         id: column
         anchors.centerIn: parent

         onChildrenChanged: optimize ? Qt.callLater(updateMinimumWidth) : updateMinimumWidth()

         property int widestChild
         function updateMinimumWidth() {
             callsToUpdateMinimumWidth++
             var w = 0;
             for (var i in children) {
                 var child = children[i];
                 if (child.implicitWidth > w) {
                     w = child.implicitWidth;
                 }
             }

             widestChild = w;
         }

         Repeater {
             id: repeater
             model: columnTexts[currentTextModel%3]
             delegate: Text {
                 color: "white"
                 text: modelData
                 width: column.widestChild
                 horizontalAlignment: Text.Center
                 Rectangle { anchors.fill: parent; z: -1; color: index%2 ? "gray" : "darkgray" }
             }
         }
     }
 }

Any additional arguments passed to Qt.callLater() will be passed on to the function invoked. Note that if redundant calls are eliminated, then only the last set of arguments will be passed to the function.

This QML method was introduced in Qt 5.8.

ASCII to binary - this function decodes the base64 encoded data string and returns it.

Returns a JavaScript object representing a property binding, with a function that evaluates the binding.

There are two main use-cases for the function: firstly, to apply a property binding imperatively from JavaScript code:

 Item {
     property bool someCondition: true
     property int edgePosition

     Component.onCompleted: {
         if (someCondition == true) {
             // bind to the result of the binding expression passed to Qt.binding()
             edgePosition = Qt.binding(function() { return x + width })
         }
     }
 }

and secondly, to apply a property binding when initializing property values of dynamically constructed objects (via Component.createObject() or Loader.setSource()).

For example, assuming the existence of a DynamicText component:

 import QtQuick 2.0

 Text {
     id: textElement
     width: 200
     height: 200
     text: "Default text"
     property string dynamicText: "Dynamic text"
     onTextChanged: console.log(text)
 }

the output from:

 Item {
     id: root
     property string dynamicText: "Root text"

     Component.onCompleted: {
         var c = Qt.createComponent("DynamicText.qml")

         var obj1 = c.createObject(root, { 'text': Qt.binding(function() { return dynamicText + ' extra text' }) })
         root.dynamicText = "Modified root text"

         var obj2 = c.createObject(root, { 'text': Qt.binding(function() { return this.dynamicText + ' extra text' }) })
         obj2.dynamicText = "Modified dynamic text"
     }
 }

and from:

 Item {
     id: root
     property string dynamicText: "Root text"

     Loader {
         id: loaderOne
         onLoaded: root.dynamicText = "Modified root text"
     }

     Loader {
         id: loaderTwo
         onLoaded: item.dynamicText = "Modified dynamic text"
     }

     Component.onCompleted: {
         loaderOne.setSource("DynamicText.qml", { 'text': Qt.binding(function() { return dynamicText + ' extra text' }) })
         loaderTwo.setSource("DynamicText.qml", { 'text': Qt.binding(function() { return this.dynamicText + ' extra text' }) })
     }
 }

should both be:

 Root text extra text
 Modified root text extra text
 Dynamic text extra text
 Modified dynamic text extra text

This function cannot be used in property binding declarations (see the documentation on binding declarations and binding assignments) except when the result is stored in an array bound to a var property.

 Item {
     width: 50
     property var storedBindings: [ Qt.binding(function() { return x + width }) ] // stored
     property int a: Qt.binding(function() { return x + width }) // error!
     property int b

     Component.onCompleted: {
         b = storedBindings[0] // causes binding assignment
     }
 }

This method was introduced in Qt 5.0.

Binary to ASCII - this function returns a base64 encoding of data.

Returns true if both lhs and rhs yield equal color values. Both arguments may be either color values or string values. If a string value is supplied it must be convertible to a color, as described for the color basic type.

Returns a Component object created using the QML file at the specified url, or null if an empty string was given.

The returned component's Component::status property indicates whether the component was successfully created. If the status is Component.Error, see Component::errorString() for an error description.

If the optional mode parameter is set to Component.Asynchronous, the component will be loaded in a background thread. The Component::status property will be Component.Loading while it is loading. The status will change to Component.Ready if the component loads successfully, or Component.Error if loading fails. This parameter defaults to Component.PreferSynchronous if omitted.

If mode is set to Component.PreferSynchronous, Qt will attempt to load the component synchronously, but may end up loading it asynchronously if necessary. Scenarios that may cause asynchronous loading include, but are not limited to, the following:

• The URL refers to a network resource
• The component is being created as a result of another component that is being loaded asynchronously

If the optional parent parameter is given, it should refer to the object that will become the parent for the created Component object. If no mode was passed, this can be the second argument.

Call Component.createObject() on the returned component to create an object instance of the component.

For example:

 import QtQuick 2.0

 Item {
     id: container
     width: 300; height: 300

     function loadButton() {
         var component = Qt.createComponent("Button.qml");
         if (component.status == Component.Ready) {
             var button = component.createObject(container);
             button.color = "red";
         }
     }

     Component.onCompleted: loadButton()
 }

See Dynamic QML Object Creation from JavaScript for more information on using this function.

To create a QML object from an arbitrary string of QML (instead of a file), use Qt.createQmlObject().

Returns a new object created from the given qml string which will have the specified parent, or null if there was an error in creating the object.

If filepath is specified, it will be used for error reporting for the created object.

Example (where parentItem is the id of an existing QML item):

 var newObject = Qt.createQmlObject('import QtQuick 2.0; Rectangle {color: "red"; width: 20; height: 20}',
                                    parentItem,
                                    "dynamicSnippet1");

In the case of an error, a Qt Script Error object is thrown. This object has an additional property, qmlErrors, which is an array of the errors encountered. Each object in this array has the members lineNumber, columnNumber, fileName and message. For example, if the above snippet had misspelled color as 'colro' then the array would contain an object like the following: { "lineNumber" : 1, "columnNumber" : 32, "fileName" : "dynamicSnippet1", "message" : "Cannot assign to non-existent property "colro""}.

Note that this function returns immediately, and therefore may not work if the qml string loads new components (that is, external QML files that have not yet been loaded). If this is the case, consider using Qt.createComponent() instead.

See Dynamic QML Object Creation from JavaScript for more information on using this function.

Returns a color darker than baseColor by the factor provided.

If the factor is greater than 1.0, this function returns a darker color. Setting factor to 3.0 returns a color that has one-third the brightness. If the factor is less than 1.0, the return color is lighter, but we recommend using the Qt.lighter() function for this purpose. If the factor is 0 or negative, the return value is unspecified.

The function converts the current RGB color to HSV, divides the value (V) component by factor and converts the color back to RGB.

If factor is not supplied, returns a color that is 50% darker than baseColor (factor 2.0).

This function causes the QQmlEngine::exit(int) signal to be emitted. Within the Prototyping with qmlscene, this causes the launcher application to exit the specified return code (retCode). To exit from the event loop with a specified return code when this method is called, a C++ application can connect the QQmlEngine::exit(int) signal to the QCoreApplication::exit(int) slot.

See also quit().

Returns a font with the properties specified in the fontSpecifier object or the nearest matching font. The fontSpecifier object should contain key-value pairs where valid keys are the font type's subproperty names, and the values are valid values for each subproperty. Invalid keys will be ignored.

Returns a list of the font families available to the application.

Returns a string representation of date, optionally formatted using format.

The date parameter may be a JavaScript Date object, a date property, a QDate, or QDateTime value. The format and localeFormatOption parameter may be any of the possible format values as described for Qt.formatDateTime().

If format is not specified, date is formatted using Locale.ShortFormat using the default locale.

See also Locale.

Returns a string representation of dateTime, optionally formatted using format and localeFormatOption.

The dateTime parameter may be a JavaScript Date object, a date property, a QDate, QTime, or QDateTime value.

If format is not provided, dateTime is formatted using Locale.ShortFormat using the default locale. Otherwise, format should be either:

• One of the Qt::DateFormat enumeration values, such as Qt.RFC2822Date or Qt.ISODate.
• A string that specifies the format of the returned string, as detailed below.
• A locale object.

If format specifies a locale object, dateTime is formatted with QLocale::toString. In this case, localeFormatOption can hold a value of type QLocale::FormatType to further tune the formatting. If none is provided, Locale.ShortFormat is used.

If format specifies a format string, it should use the following expressions to specify the date:

In addition the following expressions can be used to specify the time:

All other input characters will be ignored. Any sequence of characters that are enclosed in single quotes will be treated as text and not be used as an expression. Two consecutive single quotes ("''") are replaced by a single quote in the output.

For example, if the following date/time value was specified:

 // 21 May 2001 14:13:09
 var dateTime = new Date(2001, 5, 21, 14, 13, 09)

This dateTime value could be passed to Qt.formatDateTime(), Qt.formatDate() or Qt.formatTime() with the format values below to produce the following results:

See also Locale.

Returns a string representation of time, optionally formatted using format, and, if provided, localeFormatOption.

The time parameter may be a JavaScript Date object, a QTime, or QDateTime value. The format and localeFormatOption parameter may be any of the possible format values as described for Qt.formatDateTime().

If format is not specified, time is formatted using Locale.ShortFormat using the default locale.

See also Locale.

Returns a color with the specified hue, saturation, lightness, and alpha components. All components should be in the range 0-1 (inclusive).

Returns a color with the specified hue, saturation, value and alpha components. All components should be in the range 0-1 (inclusive).

This method was introduced in Qt 5.5.

Returns true if object is a valid reference to a Qt or QML object, false otherwise.

Returns a color lighter than baseColor by the factor provided.

If the factor is greater than 1.0, this functions returns a lighter color. Setting factor to 1.5 returns a color that is 50% brighter. If the factor is less than 1.0, the return color is darker, but we recommend using the Qt.darker() function for this purpose. If the factor is 0 or negative, the return value is unspecified.

The function converts the current RGB color to HSV, multiplies the value (V) component by factor and converts the color back to RGB.

If factor is not supplied, returns a color that is 50% lighter than baseColor (factor 1.5).

Returns a JS object representing the locale with the specified name, which has the format "language[_territory][.codeset][@modifier]" or "C", where:

• language is a lowercase, two-letter, ISO 639 language code,
• territory is an uppercase, two-letter, ISO 3166 country code, and
• codeset and modifier are ignored.

If the string violates the locale format, or language is not a valid ISO 369 code, the "C" locale is used instead. If country is not present, or is not a valid ISO 3166 code, the most appropriate country is chosen for the specified language.

See also Locale.

Returns a hex string of the md5 hash of data.

Returns a matrix4x4 with the specified values.

The arguments correspond to their positions in the matrix:

Alternatively, the function may be called with a single argument where that argument is a JavaScript array which contains the sixteen matrix values.

Finally, the function may be called with no arguments and the resulting matrix will be the identity matrix.

Attempts to open the specified target url in an external application, based on the user's desktop preferences. Returns true if it succeeds, false otherwise.

Warning: A return value of true indicates that the application has successfully requested the operating system to open the URL in an external application. The external application may still fail to launch or fail to open the requested URL. This result will not be reported back to the application.

Returns a point with the specified x and y coordinates.

Returns a translated version of sourceText, optionally based on a disambiguation string and value of n for strings containing plurals; otherwise returns sourceText itself if no appropriate translated string is available.

If the same sourceText is used in different roles within the same translation context, an additional identifying string may be passed in for disambiguation.

Example:

 Text { text: qsTr("hello") }

See also Internationalization and Localization with Qt Quick.

Returns a translated string identified by id. If no matching string is found, the id itself is returned. This should not happen under normal conditions.

If n >= 0, all occurrences of %n in the resulting string are replaced with a decimal representation of n. In addition, depending on n's value, the translation text may vary.

Example:

 Text { text: qsTrId("hello_id") }

It is possible to supply a source string template like:

//% <string>

or

\begincomment% <string> \endcomment

Example:

 Text {
     //% "hello"
     text: qsTrId("hello_id")
 }

Creating binary translation (QM) files suitable for use with this function requires passing the -idbased option to the lrelease tool.

See also QT_TRID_NOOP() and Internationalization and Localization with Qt Quick.

Marks id for dynamic translation.

Returns the id.

QT_TRID_NOOP is used in conjunction with the dynamic translation function qsTrId(). It identifies a string as requiring translation (so it can be identified by lupdate), but leaves the actual translation to qsTrId().

Example:

 Item {
     property string greetingId: QT_TRID_NOOP("hello_id")

     Text { text: qsTrId(greetingId) }
 }

See also qsTrId() and Internationalization and Localization with Qt Quick.

Marks sourceText for dynamic translation; i.e, the stored sourceText will not be altered.

If the same sourceText is used in different roles within the same translation context, an additional identifying string may be passed in for disambiguation.

Returns the sourceText.

QT_TR_NOOP is used in conjunction with the dynamic translation functions qsTr() and qsTranslate(). It identifies a string as requiring translation (so it can be identified by lupdate), but leaves the actual translation to the dynamic functions.

Example:

 Item {
     property string greeting: QT_TR_NOOP("hello")

     Text { text: qsTr(greeting) }
 }

See also Internationalization and Localization with Qt Quick.

Returns a translated version of sourceText within the given context, optionally based on a disambiguation string and value of n for strings containing plurals; otherwise returns sourceText itself if no appropriate translated string is available.

If the same sourceText is used in different roles within the same translation context, an additional identifying string may be passed in for disambiguation.

Example:

 Text { text: qsTranslate("CustomContext", "hello") }

See also Internationalization and Localization with Qt Quick.

Marks sourceText for dynamic translation in the given context; i.e, the stored sourceText will not be altered.

If the same sourceText is used in different roles within the same translation context, an additional identifying string may be passed in for disambiguation.

Returns the sourceText.

QT_TRANSLATE_NOOP is used in conjunction with the dynamic translation functions qsTr() and qsTranslate(). It identifies a string as requiring translation (so it can be identified by lupdate), but leaves the actual translation to the dynamic functions.

Example:

 Item {
     property string greeting: QT_TRANSLATE_NOOP("CustomContext", "hello")

     Text { text: qsTranslate("CustomContext", greeting) }
 }

See also Internationalization and Localization with Qt Quick.

Returns a quaternion with the specified scalar, x, y, and z values.

This function causes the QQmlEngine::quit() signal to be emitted. Within the Prototyping with qmlscene, this causes the launcher application to exit; to quit a C++ application when this method is called, connect the QQmlEngine::quit() signal to the QCoreApplication::quit() slot.

See also exit().

Returns a rect with the top-left corner at x, y and the specified width and height.

Returns url resolved relative to the URL of the caller.

Returns a color with the specified red, green, blue, and alpha components. All components should be in the range 0-1 (inclusive).

Returns a size with the specified width and height.

This function allows tinting one color (baseColor) with another (tintColor).

The tint color should usually be mostly transparent, or you will not be able to see the underlying color. The below example provides a slight red tint by having the tint color be pure red which is only 1/16th opaque.

 Item {
     Rectangle {
         x: 0; width: 80; height: 80
         color: "lightsteelblue"
     }
     Rectangle {
         x: 100; width: 80; height: 80
         color: Qt.tint("lightsteelblue", "#10FF0000")
     }
 }

Tint is most useful when a subtle change is intended to be conveyed due to some event; you can then use tinting to more effectively tune the visible color.

Returns a vector2d with the specified x and y values.

Returns a vector3d with the specified x, y, and z values.

Returns a vector4d with the specified x, y, z, and w values.